u-boot: upgrade to 2016.11 based version

0001-fw_env.c-include-stdint.h-unconditionally.patch has been fixed upstream.

Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
Acked-by: Stefan Agner <stefan.agner@toradex.com>

1 files changed, 48 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-toradex_2016.11.bb b/recipes-bsp/u-boot/u-boot-toradex_2016.11.bb
new file mode 100644
index 0000000..d2a979d
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-toradex_2016.11.bb
@@ -0,0 +1,48 @@
+include recipes-bsp/u-boot/u-boot-toradex.inc
+
+PV = "v2016.11-v2.6.2b1+git${SRCPV}"
+
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=a2c678cfd4a4d97135585cad908541c6"
+
+SRCREV = "0cca0bafe5a9690c68a0ec971a520b61a09714b5"
+SRCBRANCH = "2016.11-toradex-next"
+COMPATIBLE_MACHINE = "(mx6|mx7|vf)"
+
+
+# Hack around building two U-Boot configurations, one with, one without SPL
+# if using UBOOT_CONFIG to build more than one configuration, the current code in
+# u-boot.inc assumes all are either with or without SPL.
+do_deploy_prepend_mx6() {
+    for config in ${UBOOT_MACHINE}; do
+        touch ${B}/${config}/${SPL_BINARY}
+    done
+}
+do_deploy_append_mx6() {
+    # if SPL is zero sized file, remove all deployed artefacts
+    if [ -n "${SPL_BINARY}" ]
+    then
+        if [ -n "${UBOOT_CONFIG}" ]
+        then
+            for config in ${UBOOT_MACHINE}; do
+                i=$(expr $i + 1);
+                for type in ${UBOOT_CONFIG}; do
+                    j=$(expr $j + 1);
+                    if [ $j -eq $i ]
+                    then
+                        if [ ! -s ${DEPLOYDIR}/${SPL_IMAGE}-${type}-${PV}-${PR} ]
+                        then
+                            rm -f ${DEPLOYDIR}/${SPL_IMAGE}-${type}-${PV}-${PR}
+                            rm -f ${DEPLOYDIR}/${SPL_BINARYNAME}-${type}
+                            rm -f ${DEPLOYDIR}/${SPL_SYMLINK}-${type}
+                            rm -f ${DEPLOYDIR}/${SPL_SYMLINK}
+                        else
+                            ln -sf ${SPL_IMAGE}-${type}-${PV}-${PR} ${SPL_BINARYNAME}
+                        fi
+                    fi
+                done
+                unset  j
+            done
+            unset  i
+        fi
+    fi
+}