blob: 45418cf6fcc0fede4760bfe9e4230e1bcf4ece34 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
IMX_FIRMWARE_SRC ?= "git://github.com/NXP/imx-firmware.git;protocol=https"
SRCBRANCH_imx-firmware = "lf-6.6.3_1.0.0"
SRC_URI += " \
${IMX_FIRMWARE_SRC};branch=${SRCBRANCH_imx-firmware};destsuffix=${UNPACKDIR}/imx-firmware;name=imx-firmware \
"
SRCREV_imx-firmware = "2afa15e77f0b58eade42b4f59c9215339efcca66"
SRCREV_FORMAT = "default_imx-firmware"
do_patch:append() {
src = oe.path.join(d.getVar("UNPACKDIR"), "/imx-firmware")
dest = oe.path.join(d.getVar("S"), "/imx-firmware")
oe.path.copyhardlinktree(src, dest)
}
do_install:append () {
# Install IMX Firmware EULA/LICENSE license
install -d ${D}${nonarch_base_libdir}/firmware
install -m 0644 imx-firmware/LICENSE.txt ${D}${nonarch_base_libdir}/firmware/LICENSE.imx
# Install common IMX firmware files
install -d ${D}${nonarch_base_libdir}/firmware/nxp
install -m 0644 imx-firmware/nxp/wifi_mod_para.conf ${D}${nonarch_base_libdir}/firmware/nxp
# Install NXP Connectivity SDIO8997 firmware
install -m 0644 imx-firmware/nxp/FwImage_8997_SD/ed_mac_ctrl_V3_8997.conf ${D}${nonarch_base_libdir}/firmware/nxp
install -m 0644 imx-firmware/nxp/FwImage_8997_SD/sdiouart8997_combo_v4.bin ${D}${nonarch_base_libdir}/firmware/nxp
install -m 0644 imx-firmware/nxp/FwImage_8997_SD/txpwrlimit_cfg_8997.conf ${D}${nonarch_base_libdir}/firmware/nxp
# Upstream SDIO8997 driver firmware is located elsewhere
install -d ${D}${nonarch_base_libdir}/firmware/mrvl
ln -frs ${D}${nonarch_base_libdir}/firmware/nxp/sdiouart8997_combo_v4.bin ${D}${nonarch_base_libdir}/firmware/mrvl/sdiouart8997_combo_v4.bin
# Install IW416 firmware
install -m 0644 imx-firmware/nxp/FwImage_IW416_SD/sdiouartiw416_combo_v0.bin ${D}${nonarch_base_libdir}/firmware/nxp
ln -frs ${D}${nonarch_base_libdir}/firmware/nxp/sdiouartiw416_combo_v0.bin ${D}${nonarch_base_libdir}/firmware/mrvl/sdiouartiw416_combo_v0.bin
}
LICENSE += " \
& firmware-imx \
"
LIC_FILES_CHKSUM += " \
file://imx-firmware/LICENSE.txt;md5=44a8052c384584ba09077e85a3d1654f \
"
NO_GENERIC_LICENSE[firmware-imx] = "imx-firmware/LICENSE.txt"
PACKAGES =+ " \
${PN}-imx-common \
${PN}-imx-license \
${PN}-iw416 \
${PN}-nxp89xx \
"
FILES:${PN}-imx-common = "${nonarch_base_libdir}/firmware/nxp/wifi_mod_para.conf"
FILES:${PN}-imx-license = "${nonarch_base_libdir}/firmware/LICENSE.imx"
FILES:${PN}-iw416 = " \
${nonarch_base_libdir}/firmware/mrvl/sdiouartiw416_combo_v0.bin \
${nonarch_base_libdir}/firmware/nxp/sdiouartiw416_combo_v0.bin \
"
LICENSE:${PN}-iw416 = "firmware-imx"
RDEPENDS:${PN}-iw416 += "${PN}-imx-common ${PN}-imx-license"
FILES:${PN}-nxp89xx = " \
${nonarch_base_libdir}/firmware/mrvl/sdiouart8997_combo_v4.bin \
${nonarch_base_libdir}/firmware/nxp/ed_mac_ctrl_V3_8997.conf \
${nonarch_base_libdir}/firmware/nxp/sdiouart8997_combo_v4.bin \
${nonarch_base_libdir}/firmware/nxp/txpwrlimit_cfg_8997.conf \
"
LICENSE:${PN}-nxp89xx = "firmware-imx"
RDEPENDS:${PN}-nxp89xx += "${PN}-imx-common ${PN}-imx-license"
|
