From 391e630a3bbf91d2ef7358098f9f0f179f5785c2 Mon Sep 17 00:00:00 2001
From: Max Krummenacher <max.krummenacher@toradex.com>
Date: Fri, 1 Jul 2016 21:05:17 +0200
Subject: gnome-disk-utility: add gtk3 version

add libpwquality recipe from meta-qt5-extra.

Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
Acked-by: Stefan Agner <stefan.agner@toradex.com>
---
 .../gnome-disk-utility_3.21.3.bb                   | 37 ++++++++++++++
 .../gnome-disk-utility/libpwquality_1.3.0.bb       | 59 ++++++++++++++++++++++
 2 files changed, 96 insertions(+)
 create mode 100644 recipes-gnome/gnome-disk-utility/gnome-disk-utility_3.21.3.bb
 create mode 100644 recipes-gnome/gnome-disk-utility/libpwquality_1.3.0.bb

(limited to 'recipes-gnome/gnome-disk-utility')

diff --git a/recipes-gnome/gnome-disk-utility/gnome-disk-utility_3.21.3.bb b/recipes-gnome/gnome-disk-utility/gnome-disk-utility_3.21.3.bb
new file mode 100644
index 0000000..1f6c5ab
--- /dev/null
+++ b/recipes-gnome/gnome-disk-utility/gnome-disk-utility_3.21.3.bb
@@ -0,0 +1,37 @@
+SUMMARY = "GNOME disk utility"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+DEPENDS = "glib-2.0 gtk+3 libcanberra libdvdread libnotify libpwquality libsecret libunique udisks2 avahi-ui virtual/libx11 libatasmart gnome-doc-utils intltool-native libgnome-keyring"
+
+PR = "r4"
+
+inherit gnomebase gtk-icon-cache
+SRC_URI[archive.md5sum] = "265ed1aede9ef0570228ca6908e9df59"
+SRC_URI[archive.sha256sum] = "f39508226268f39dafa8977ebcec1d36e694f8aa7c4a404d1ac50f76e8e57739"
+GNOME_COMPRESS_TYPE="xz"
+
+#SRC_URI += "\
+#    file://disable-scrollkeeper.patch \
+#    file://fix-dbus-interfaces.patch \
+#    file://sysrooted-pkg-config.patch \
+#    file://0001-Add-support-for-DeviceAutomountHint.patch \
+#    file://0002-Require-libnotify-0.6.1.patch \
+#"
+
+EXTRA_OECONF += "--disable-scrollkeeper --disable-gsd-plugin"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[nautilus] = "--enable-nautilus,--disable-nautilus,nautilus"
+
+do_configure_prepend() {
+    sed -i -e "s: help : :g" ${S}/Makefile.am
+}
+
+PACKAGES =+ "${PN}-nautilus-extension ${PN}-libs"
+FILES_${PN}-nautilus-extension += "${libdir}/nautilus/extensions-2.0/*.so"
+FILES_${PN}-libs += "${libdir}/libgdu*.so.*"
+FILES_${PN}-dev += "${libdir}/nautilus/extensions-2.0/*.la"
+FILES_${PN}-staticdev += "${libdir}/nautilus/extensions-2.0/*.a"
+FILES_${PN}-dbg += "${libdir}/nautilus/extensions-2.0/.debug"
diff --git a/recipes-gnome/gnome-disk-utility/libpwquality_1.3.0.bb b/recipes-gnome/gnome-disk-utility/libpwquality_1.3.0.bb
new file mode 100644
index 0000000..bff7fc8
--- /dev/null
+++ b/recipes-gnome/gnome-disk-utility/libpwquality_1.3.0.bb
@@ -0,0 +1,59 @@
+SUMMARY = "Library for password quality checking and generating random passwords"
+HOMEPAGE = "https://launchpad.net/libpwquality"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bd2f1386df813a459a0c34fde676fc2"
+
+SRC_URI = "https://launchpad.net/${BPN}/trunk/${PV}/+download/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "2a3d4ba1d11b52b4f6a7f39622ebf736"
+SRC_URI[sha256sum] = "74d2ea90e103323c1f2d6a6cc9617cdae6877573eddb31aaf31a40f354cc2d2a"
+
+inherit autotools-brokensep pkgconfig gettext pythonnative
+
+DEPENDS = "zlib cracklib libpam python"
+
+EXTRA_OECONF = " \
+    --with-securedir=${base_libdir}/security \
+    --with-python-binary=${PYTHON} \
+"
+
+do_compile() {
+    # make distustils part for python bindings happy
+    export STAGING_INCDIR=${STAGING_INCDIR}
+    export STAGING_LIBDIR=${STAGING_LIBDIR}
+    export BUILD_SYS=${BUILD_SYS}
+    export HOST_SYS=${HOST_SYS}
+    base_do_compile
+}
+
+do_install() {
+    # make distustils part for python bindings happy
+    export STAGING_INCDIR=${STAGING_INCDIR}
+    export STAGING_LIBDIR=${STAGING_LIBDIR}
+    export BUILD_SYS=${BUILD_SYS}
+    export HOST_SYS=${HOST_SYS}
+    autotools_do_install
+}
+
+FILES_${PN} += " \
+    ${base_libdir}/security/*.so \
+"
+
+PACKAGE_BEFORE_PN += "${PN}-python"
+
+FILES_${PN}-python = " \
+    ${PYTHON_SITEPACKAGES_DIR} \
+"
+
+FILES_${PN}-staticdev += " \
+    ${PYTHON_SITEPACKAGES_DIR}/*.a \
+    ${base_libdir}/security/*.a \
+"
+FILES_${PN}-dev += " \
+    ${PYTHON_SITEPACKAGES_DIR}/*.la \
+    ${base_libdir}/security/*.la \
+"
+
+FILES_${PN}-dbg += "\
+    ${PYTHON_SITEPACKAGES_DIR}/.debug \
+    ${base_libdir}/security/.debug \
+"
-- 
cgit v1.2.3