summaryrefslogtreecommitdiff
path: root/recipes-images/images/packagegroup-tdx-graphical.bb
blob: 1da55885762b7e037bb1635df11da8519dcf26a1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
SUMMARY = "Packagegroups which provide graphical/display/multimedia releated packages"

PACKAGE_ARCH = "${MACHINE_ARCH}"

inherit packagegroup

PROVIDES = "${PACKAGES}"
PACKAGES += " \
    packagegroup-drm-utils-tdx-graphical \
    packagegroup-gstreamer-tdx-graphical \
    packagegroup-gpu-tdx-graphical \
    packagegroup-x11-components-tdx-graphical \
    packagegroup-x11-utils-tdx-graphical \
"

RRECOMMENDS_packagegroup-tdx-graphical = " \
    packagegroup-gstreamer-tdx-graphical \
    packagegroup-gpu-tdx-graphical \
    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '', \
       bb.utils.contains('DISTRO_FEATURES', 'x11', \
                         'packagegroup-x11-components-tdx-graphical \
                          packagegroup-x11-utils-tdx-graphical', \
                         '', d), d)} \
"
RRECOMMENDS_packagegroup-tdx-graphical_append_mx8 = " \
    packagegroup-drm-utils-tdx-graphical \
"
RRECOMMENDS_packagegroup-tdx-graphical_append_upstream = " \
    packagegroup-drm-utils-tdx-graphical \
"

SUMMARY_packagegroup-drm-utils-tdx-graphical = "Utilities for DRM, Direct Rendering Manager"
RRECOMMENDS_packagegroup-drm-utils-tdx-graphical = " \
    libdrm-tests \
"

SUMMARY_packagegroup-gstreamer-tdx-graphical = "gstreamer packages"
RRECOMMENDS_packagegroup-gstreamer-tdx-graphical = "\
    gstreamer1.0 \
    gstreamer1.0-plugins-base \
    gstreamer1.0-plugins-good \
    gstreamer1.0-plugins-bad \
"
GSTREAMER_MX6QDL = " \
    gstreamer1.0-plugins-base-ximagesink \
    gstreamer1.0-plugins-imx \
"
RRECOMMENDS_packagegroup-gstreamer-tdx-graphical_append_mx6dl = " ${GSTREAMER_MX6QDL}"
RRECOMMENDS_packagegroup-gstreamer-tdx-graphical_append_mx6q = " ${GSTREAMER_MX6QDL}"
RRECOMMENDS_packagegroup-gstreamer-tdx-graphical_colibri-imx6ull = ""
RRECOMMENDS_packagegroup-gstreamer-tdx-graphical_append_mx7 = " imx-gst1.0-plugin"
RRECOMMENDS_packagegroup-gstreamer-tdx-graphical_append_mx8 = " \
    imx-gst1.0-plugin \
    imx-gst1.0-plugin-gplay \
    imx-gst1.0-plugin-grecorder \
    packagegroup-fsl-gstreamer1.0-full \
    gst-examples \
"

SUMMARY_packagegroup-gpu-utils-tdx-graphical = "Utilities for GPU (OpenGL...)"
IMAGE_INSTALL_OPENCL_IMX = " \
    clpeak \
    libopencl-imx \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical = " \
    glmark2 \
"
IMAGE_INSTALL_GPU_MX6QDL = " \
    packagegroup-fsl-gpu-libs \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical_append_mx6dl = " \
    ${IMAGE_INSTALL_GPU_MX6QDL} \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical_append_mx6q = " \
    ${IMAGE_INSTALL_GPU_MX6QDL} \
    ${IMAGE_INSTALL_OPENCL_IMX} \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical_colibri-imx6ull = ""
RRECOMMENDS_packagegroup-gpu-tdx-graphical_append_mx8 = " \
    tinycompress \
    libvdk-imx \
    vulkan-headers \
    vulkan-loader \
    vulkan-tools \
    ${IMAGE_INSTALL_OPENCL_IMX} \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical_remove_mx8mm = " \
    vulkan \
    ${IMAGE_INSTALL_OPENCL_IMX} \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical_append_mx8qm = " \
    libopenvx-imx \
"
RRECOMMENDS_packagegroup-gpu-tdx-graphical_append_tegra124 = " \
    libglu \
    freeglut \
    tiff \
    xvinfo \
"

SUMMARY_packagegroup-x11-components-tdx-graphical = "Components of X11"
RRECOMMENDS_packagegroup-x11-components-tdx-graphical = "\
    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '', \
       bb.utils.contains('DISTRO_FEATURES', 'x11', \
       'libxcursor \
        libxdamage \
        libxres \
        libxvmc \
        xcursor-transparent-theme \
        xorg-minimal-fonts \
        xrdb \
        xserver-xorg-extension-dbe \
        xserver-xorg-extension-extmod \
        xserver-xorg-multimedia-modules \
        xserver-xorg-utils', \
       '', d), d)} \
"

SUMMARY_packagegroup-x11-utils-tdx-graphical = "Utilities for X11"
RRECOMMENDS_packagegroup-x11-utils-tdx-graphical = " \
    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '', \
       bb.utils.contains('DISTRO_FEATURES', 'x11', \
       'scrot \
        setxkbmap \
        unclutter', \
       '', d), d)} \
"