u-boot-toradex: update to nxp 2020.04

Related-to: ELB-2758
Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>

1 files changed, 46 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-toradex-common_2020.04.inc b/recipes-bsp/u-boot/u-boot-toradex-common_2020.04.inc
new file mode 100644
index 0000000..6142373
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-toradex-common_2020.04.inc
@@ -0,0 +1,46 @@
+HOMEPAGE = "http://www.denx.de/wiki/U-Boot/WebHome"
+SECTION = "bootloaders"
+DEPENDS += "flex-native bison-native"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRC_URI = " \
+    git://git.toradex.com/u-boot-toradex.git;protocol=https;branch=${SRCBRANCH} \
+    file://fw_env.config \
+"
+
+SRCREV = "111b5f6dd839f4f164ad327e08792bff8a733ab3"
+SRCREV_use-head-next = "${AUTOREV}"
+SRCBRANCH = "toradex_imx_v2020.04_5.4.24_2.1.0"
+
+S = "${WORKDIR}/git"
+
+inherit toradex-u-boot-localversion
+
+UBOOT_INITIAL_ENV = "u-boot-initial-env"
+
+COMPATIBLE_MACHINE = "(mx8)"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_deploy_append_mx8m() {
+    # Deploy the mkimage, u-boot-nodtb.bin and fsl-imx8m*-XX.dtb for mkimage to generate boot binary
+    if [ -n "${UBOOT_CONFIG}" ]
+    then
+        for config in ${UBOOT_MACHINE}; do
+            i=$(expr $i + 1);
+            for type in ${UBOOT_CONFIG}; do
+                j=$(expr $j + 1);
+                if [ $j -eq $i ]
+                then
+                    install -d ${DEPLOYDIR}/${BOOT_TOOLS}
+                    install -m 0777 ${B}/${config}/arch/arm/dts/${UBOOT_DTB_NAME}  ${DEPLOYDIR}/${BOOT_TOOLS}
+                    install -m 0777 ${B}/${config}/tools/mkimage  ${DEPLOYDIR}/${BOOT_TOOLS}/mkimage_uboot
+                    install -m 0777 ${B}/${config}/u-boot-nodtb.bin  ${DEPLOYDIR}/${BOOT_TOOLS}/u-boot-nodtb.bin-${MACHINE}-${UBOOT_CONFIG}
+                fi
+            done
+            unset  j
+        done
+        unset  i
+    fi
+}