u-boot-toradex: update to 2019.07

Update to a 2019.07 based U-Boot.
Use the openembedded master recipes for u-boot_2019.07 as a base.

This makes the u-boot recipe in recipes-bsp/u-boot-mainline/ obsolete,
delete it.

Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>

1 files changed, 72 insertions, 0 deletions

diff --git a/recipes-bsp/u-boot/u-boot-toradex-fw-utils_2019.07.bb b/recipes-bsp/u-boot/u-boot-toradex-fw-utils_2019.07.bb
new file mode 100644
index 0000000..3f036c1
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-toradex-fw-utils_2019.07.bb
@@ -0,0 +1,72 @@
+require u-boot-toradex-common.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS += "mtd-utils"
+
+SRC_URI += " \
+    file://fw_env.config \
+    file://fw_unlock_mmc.sh \
+"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'HOSTCC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+    oe_runmake ${UBOOT_MACHINE}
+    oe_runmake envtools
+}
+
+do_install () {
+    install -d ${D}${base_sbindir}
+    install -d ${D}${sysconfdir}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+    ln -s fw_printenv ${D}${base_sbindir}/fw_setenv
+
+    if [ -e ${WORKDIR}/fw_env.config ]; then
+        install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+    else
+        install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+    fi
+}
+
+install_unlock_emmc() {
+    install -d ${D}${sysconfdir}/profile.d/
+    install -m 0644 ${WORKDIR}/fw_unlock_mmc.sh ${D}${sysconfdir}/profile.d/fw_unlock_mmc.sh
+}
+
+do_install_append_apalis-imx6() {
+    install_unlock_emmc
+}
+
+do_install_append_colibri-imx6() {
+    install_unlock_emmc
+}
+
+do_install_append_colibri-imx7-emmc() {
+    install_unlock_emmc
+}
+
+do_install_append_apalis-imx8() {
+    install_unlock_emmc
+}
+
+do_install_append_colibri-imx8x() {
+    install_unlock_emmc
+}
+
+do_install_class-cross () {
+    install -d ${D}${bindir_cross}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
+
+PROVIDES += "u-boot-fw-utils"
+RPROVIDES_${PN} += "u-boot-fw-utils"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"