xf86-video-imxfb-vivante: Upgrade to 6.2.2.p0

Signed-off-by: Tom Hochstein <tom.hochstein@nxp.com>
Signed-off-by: Stefan Agner <stefan.agner@toradex.com>
Acked-by: Marcel Ziswiler <marcel.ziswiler@toradex.com>

3 files changed, 124 insertions, 0 deletions

diff --git a/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante.inc b/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante.inc
new file mode 100644
index 0000000..c16da67
--- /dev/null
+++ b/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante.inc
@@ -0,0 +1,73 @@
+# Copyright (C) 2012-2015 Freescale Semiconductor
+# Copyright (C) 2012-2016 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require recipes-graphics/xorg-driver/xorg-driver-video.inc
+
+PE = "3"
+
+inherit autotools-brokensep update-rc.d pkgconfig
+
+DEPENDS += "virtual/xserver virtual/libx11 virtual/libgal-x11 imx-gpu-viv virtual/libg2d pixman"
+
+LIC_FILES_CHKSUM = "file://COPYING-MIT;md5=b5e9d9f5c02ea831ab3ecf802bb7c4f3"
+
+SRC_URI = "git://source.codeaurora.org/external/imx/xf86-video-imx-vivante.git;protocol=https;branch=${SRCBRANCH} \
+           file://rc.autohdmi"
+
+S = "${WORKDIR}/git/"
+
+INITSCRIPT_PACKAGES = "xserver-xorg-extension-viv-autohdmi"
+INITSCRIPT_NAME = "rc.autohdmi"
+INITSCRIPT_PARAMS = "start 99 2 3 4 5 ."
+
+EXTRA_OEMAKE += "prefix=${D}/usr \
+                 sysroot=${STAGING_DIR_TARGET} \
+                 LFLAGS="${LDFLAGS}" \
+                 BUSID_HAS_NUMBER=1 \
+                 BUILD_IN_YOCTO=1 \
+                 XSERVER_GREATER_THAN_13=1"
+
+CFLAGS += "-I${STAGING_INCDIR}/xorg \
+           -I${STAGING_INCDIR}/drm \
+           -I../../DRI_1.10.4/src"
+
+PACKAGES =+ "xserver-xorg-extension-viv-autohdmi"
+
+# FIXME: The Freescale provided Makefile has hardcodec include paths
+#        and this does not work in case prefix is different than /usr,
+#        sed it.
+do_configure_prepend () {
+    sed -i 's,$(sysroot)/usr/include,${STAGING_INCDIR},g' \
+            ${S}EXA/src/makefile.linux
+}
+
+do_install_append () {
+	install -d ${D}${includedir}
+	cp -axr ${S}/EXA/src/vivante_gal/vivante_priv.h ${D}${includedir}
+	cp -axr ${S}/EXA/src/vivante_gal/vivante_gal.h ${D}${includedir}
+
+	install -d ${D}/${sysconfdir}/init.d
+	install -m 755 ${WORKDIR}/rc.autohdmi ${D}/${sysconfdir}/init.d/rc.autohdmi
+
+	find ${D}${includedir} -type f -exec chmod 660 {} \;
+}
+
+RDEPENDS_${PN} += "libvivante-dri-imx \
+                   xserver-xorg-module-exa \
+                   mesa-driver-swrast \
+                   xserver-xorg-extension-dri \
+                   xserver-xorg-extension-dri2 \
+                   xserver-xorg-extension-glx"
+
+REALSOLIBS := "${SOLIBS}"
+SOLIBS = "${SOLIBSDEV}"
+
+FILES_${PN} = "${libdir}/*/*/*/vivante_drv${SOLIBS}"
+FILES_${PN}-dev = "${includedir} /usr/src ${libdir}/libfsl_x11_ext${SOLIBSDEV}"
+FILES_${PN}-dbg = "${libdir}/*/*/*/.debug ${libdir}/.debug/libfsl_x11_ext${SOLIBS} ${exec_prefix}/bin/.debug/autohdmi"
+
+FILES_xserver-xorg-extension-viv-autohdmi = " ${libdir}/libfsl_x11_ext${SOLIBS} ${exec_prefix}/bin/autohdmi ${sysconfdir}/init.d/rc.autohdmi"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(mx6|mx7ulp)"
diff --git a/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante/rc.autohdmi b/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante/rc.autohdmi
new file mode 100644
index 0000000..8c16a1d
--- /dev/null
+++ b/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante/rc.autohdmi
@@ -0,0 +1,42 @@
+#! /bin/sh
+### BEGIN INIT INFO
+# Provides:          rc.autohdmi
+# Required-Start:    $all
+# Required-Stop:
+# Default-Start:     2 3 4 5
+# Default-Stop:
+### END INIT INFO
+
+PATH=/sbin:/usr/sbin:/bin:/usr/bin
+
+# Source function library.
+. /etc/init.d/functions
+
+case "$1" in
+    start)
+	echo -n "Starting autohdmi: "
+	export DISPLAY=:0
+	autohdmi &
+	echo
+	exit 0
+        ;;
+    reload|force-reload)
+        echo "Error: argument '$1' not supported" >&2
+        exit 3
+        ;;
+    stop)
+        echo -n "Shutting down autohdmi: "
+        killproc autohdmi
+        echo
+        ;;
+    restart)
+        echo -n "Restarting autohdmi: "
+        $0 stop
+        $0 start
+	echo
+        ;;
+    *)
+        echo "Usage: $0 start|stop" >&2
+        exit 3
+        ;;
+esac
diff --git a/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante_6.2.2.p0.bb b/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante_6.2.2.p0.bb
new file mode 100644
index 0000000..5514962
--- /dev/null
+++ b/recipes-graphics/xorg-driver/xf86-video-imxfb-vivante_6.2.2.p0.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2012-2016 Freescale Semiconductor
+# Copyright (C) 2012-2014 O.S. Systems Software LTDA.
+# Copyright 2017 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require xf86-video-imxfb-vivante.inc
+
+SRCBRANCH = "nxp/imx_4.9.11_1.0.0_ga"
+SRCREV = "07ef065dfe09f1c05a1a188c371577faa3677a17"