Revert "imx-codec: Upgrade version from 4.3.4 to 4.4.2"

This reverts commit 1e0a57f744b0dd42ac7025ee0ed540f940291c57.

This now lives in meta-freescale.

Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>

1 files changed, 0 insertions, 119 deletions

diff --git a/recipes-multimedia/imx-codec/imx-codec_4.4.2.bb b/recipes-multimedia/imx-codec/imx-codec_4.4.2.bb
deleted file mode 100644
index 60a3717..0000000
--- a/recipes-multimedia/imx-codec/imx-codec_4.4.2.bb
+++ /dev/null
@@ -1,119 +0,0 @@
-# Copyright (C) 2012-2016 Freescale Semiconductor
-# Copyright 2017 NXP
-# Copyright 2018 (C) O.S. Systems Software LTDA.
-# Released under the MIT license (see COPYING.MIT for the terms)
-DESCRIPTION = "Freescale Multimedia codec libs"
-LICENSE = "Proprietary"
-SECTION = "multimedia"
-LIC_FILES_CHKSUM = "file://COPYING;md5=5ab1a30d0cd181e3408077727ea5a2db"
-
-# Backward compatibility
-PROVIDES += "libfslcodec"
-
-SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
-SRC_URI[md5sum] = "6087fbac97002b7d8c5dd061e6b36417"
-SRC_URI[sha256sum] = "f225968d8efcdb8f1843adae162360df04166e91acea2c32388cf699f410bdda"
-
-inherit fsl-eula-unpack autotools pkgconfig
-
-# Choose between 32-bit and 64-bit binaries and between Soft Float-Point and Hard Float-Point
-EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '--enable-armv8', \
-                   bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '', d), d)}"
-
-PACKAGECONFIG ?= ""
-PACKAGECONFIG_imxvpu = "vpu"
-
-PACKAGECONFIG[vpu] = "--enable-vpu,--disable-vpu,virtual/imxvpu"
-
-do_install_append() {
-    # FIXME: This link points to nowhere
-    if [ -e ${D}${libdir}/imx-mm/audio-codec/lib_src_ppp_arm11_elinux.so ]; then
-        rm ${D}${libdir}/imx-mm/audio-codec/lib_src_ppp_arm11_elinux.so
-    fi
-
-    # LTIB move the files around or gst-fsl-plugin won't find them
-    for p in $(find ${D}${libdir}/imx-mm -mindepth 2 -maxdepth 2 -not -type d); do
-            mv $p ${D}${libdir}
-    done
-    rmdir ${D}${libdir}/imx-mm/video-codec
-
-}
-
-python __set_insane_skip() {
-    # Ensure we have PACKAGES expanded
-    bb.build.exec_func("read_subpackage_metadata", d)
-
-    for p in d.getVar('PACKAGES', True).split():
-        # Even though we are packaging libraries those are plugins so we
-        # shouldn't rename the packages to follow its sonames.
-        d.setVar("DEBIAN_NOAUTONAME_%s" % p, "1")
-
-        # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
-        # the source we cannot fix it. Disable the insane check for now.
-        if p == 'imx-codec-test-bin':
-            # FIXME: includes the DUT .so files so we need to deploy those
-            d.setVar("INSANE_SKIP_%s" % p, "ldflags textrel libdir file-rdeps")
-        else:
-            d.setVar("INSANE_SKIP_%s" % p, "ldflags textrel")
-}
-
-do_package_qa[prefuncs] += "__set_insane_skip"
-
-python __split_libfslcodec_plugins() {
-    codecdir = bb.data.expand('${libdir}', d)
-    do_split_packages(d, codecdir, '^lib_([^_]*).*_arm.*_elinux\.so\..*',
-                      aux_files_pattern='${libdir}/imx-mm/audio-codec/wrap/lib_%sd_wrap_arm*_elinux.so.*',
-                      output_pattern='imx-codec-%s',
-                      description='Freescale i.MX Codec (%s)',
-                      extra_depends='')
-    pkgs = d.getVar('PACKAGES', True).split()
-    for pkg in pkgs:
-        meta = pkg[10:]
-        if meta != '':
-            d.setVar('RREPLACES_%s' % pkg, ' libfslcodec-%s' % meta)
-            d.setVar('RPROVIDES_%s' % pkg, ' libfslcodec-%s' % meta)
-            d.setVar('RCONFLICTS_%s' % pkg, ' libfslcodec-%s' % meta)
-        else :
-            d.setVar('RREPLACES_%s' % pkg, ' libfslcodec')
-            d.setVar('RPROVIDES_%s' % pkg, ' libfslcodec')
-            d.setVar('RCONFLICTS_%s' % pkg, ' libfslcodec')
-}
-
-python __set_metapkg_rdepends() {
-    # Allow addition of all codecs in a image; useful specially for
-    # debugging.
-    codec_pkgs = oe.utils.packages_filter_out_system(d)
-    codec_pkgs = filter(lambda x: x not in ['imx-codec-test-bin', 'imx-codec-test-source'],
-                        codec_pkgs)
-    d.appendVar('RDEPENDS_imx-codec-meta', ' ' + ' '.join(codec_pkgs))
-}
-
-PACKAGESPLITFUNCS =+ "__split_libfslcodec_plugins __set_metapkg_rdepends"
-
-PACKAGES_DYNAMIC = "${PN}-*"
-INHIBIT_PACKAGE_STRIP = "1"
-INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
-
-PACKAGES += "${PN}-meta ${PN}-test-bin ${PN}-test-source"
-
-ALLOW_EMPTY_${PN} = "1"
-ALLOW_EMPTY_${PN}-meta = "1"
-
-# Ensure we get warnings if we miss something
-FILES_${PN} = ""
-
-FILES_${PN}-dev += "${libdir}/imx-mm/*/*${SOLIBSDEV} \
-                    ${libdir}/imx-mm/*/*/*${SOLIBSDEV} \
-                    ${libdir}/pkgconfig/*.pc ${includedir}/imx-mm/*"
-
-FILES_${PN}-test-bin += "${datadir}/imx-mm/*/examples/*/bin"
-
-FILES_${PN}-test-source += "${datadir}/imx-mm/*"
-
-# FIXME: The wrap and lib names does not match
-FILES_${PN}-oggvorbis += "${libdir}/imx-mm/audio-codec/wrap/lib_vorbisd_wrap_arm*_elinux.so.*"
-FILES_${PN}-nb += "${libdir}/imx-mm/audio-codec/wrap/lib_nbamrd_wrap_arm*_elinux.so.*"
-FILES_${PN}-wb += "${libdir}/imx-mm/audio-codec/wrap/lib_wbamrd_wrap_arm*_elinux.so.*"
-
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-COMPATIBLE_MACHINE = "(mx6|mx7|mx8)"