From ddd9b23247c0634d3f1148550419264e595613b8 Mon Sep 17 00:00:00 2001
From: Max Krummenacher <max.krummenacher@toradex.com>
Date: Tue, 21 May 2019 17:01:27 +0200
Subject: u-boot-toradex-fw-utils_2018.03: intial recipe

Copied and adapted from:
openembedded-core/meta/recipes-bsp/u-boot/u-boot-fw-utils_2018.07.bb

Signed-off-by: Max Krummenacher <max.krummenacher@toradex.com>
---
 .../u-boot/u-boot-toradex-fw-utils_2018.03.bb      | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 recipes-bsp/u-boot/u-boot-toradex-fw-utils_2018.03.bb

(limited to 'recipes-bsp/u-boot/u-boot-toradex-fw-utils_2018.03.bb')

diff --git a/recipes-bsp/u-boot/u-boot-toradex-fw-utils_2018.03.bb b/recipes-bsp/u-boot/u-boot-toradex-fw-utils_2018.03.bb
new file mode 100644
index 0000000..45eaaa4
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-toradex-fw-utils_2018.03.bb
@@ -0,0 +1,49 @@
+require u-boot-toradex-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS += "mtd-utils"
+
+SRC_URI += " \
+    file://fw_env.config \
+    file://fw_unlock_mmc.sh \
+"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'HOSTCC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+	oe_runmake ${UBOOT_MACHINE}
+	oe_runmake envtools
+}
+
+install_unlock_emmc() {
+    install -d ${D}${sysconfdir}/profile.d/
+    install -m 0644 ${WORKDIR}/fw_unlock_mmc.sh ${D}${sysconfdir}/profile.d/fw_unlock_mmc.sh
+}
+
+do_install_append_mx8() {
+    install_unlock_emmc
+}
+
+do_install () {
+    install -d ${D}${base_sbindir}
+    install -d ${D}${sysconfdir}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+    install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+}
+
+do_install_class-cross () {
+	install -d ${D}${bindir_cross}
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
+
+COMPATIBLE_MACHINE = "(mx8)"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"
-- 
cgit v1.2.3